ample-regexps.el : 【さらばバックスラッシュ】rxに語彙を追加しより理解可能な正規表現を定義する

;;; a=10のようにふつうの言語の変数設定の正規表現
(let ((assign (rx (and (regexp "[[:alnum:]_]+")
                       "="
                       (regexp "[[:alnum:]_]+")))))
  assign                            ; => "[[:alnum:]_]+=[[:alnum:]_]+"
  (string-match assign "a=10")          ; => 0
  )
;;; alnumの部分がかぶってるので変数にしてしまいましょうか。
(let* ((name '(regexp "[[:alnum:]_]+"))
       (assign (eval `(rx (and ,name "=" ,name)))))
  assign                            ; => "[[:alnum:]_]+=[[:alnum:]_]+"
  (string-match assign "a=10")          ; => 0
  )
;;; やっぱりevalまで持ち出すのは嫌だな…ample-regexpsを使おう
(require 'ample-regexps)
(define-arx arx-assign-regexp
  '((name (regexp "[[:alnum:]_]+"))))
;; arx-assign-regexpはnameという語彙が追加されたrxとして使える！
(let ((assign (arx-assign-regexp (and name "=" name))))
  assign                            ; => "[[:alnum:]_]+=[[:alnum:]_]+"
  (string-match assign "a=10")      ; => 0
  )
;; しかも (and 〜) は省略できる
(let ((assign (arx-assign-regexp name "=" name)))
  assign                            ; => "[[:alnum:]_]+=[[:alnum:]_]+"
  (string-match assign "a=10")      ; => 0
  )

(define-arx sample-rx
  '((notnewline (regexp "."))
    (chars (regexp ".+"))))
(sample-rx notnewline)                  ; => "."
(sample-rx chars)                       ; => ".+"
(sample-rx notnewline chars)            ; => "..+"

;;; たくさん語彙を定義した例。
(define-arx cond-assignment-rx
  '((alpha_ (regexp "[[:alpha:]_]"))         ;アルファベットと_
    (alnum_ (regexp "[[:alnum:]_]"))         ;アルファベットと数字と_
    (ws (* blank))                           ;whitespace
    (sym (:func (lambda (_form &rest args) ; foo -> \_<foo\_> の変換関数
                  `(and symbol-start (or ,@args) symbol-end))))
    ;; (and symbol-start (or "if" "elif" "while") symbol-end) になる
    (cond-keyword (sym "if" "elif" "while"))
    (id (sym (+ alpha_) (* alnum_)))))
(cond-assignment-rx ws)  ; => "[[:blank:]]*"
(cond-assignment-rx (sym "foo"))  ; => "\\_<\\(?:foo\\)\\_>"
(cond-assignment-rx (sym "foo" "bar"))  ; => "\\_<\\(?:bar\\|foo\\)\\_>"
(let ((id (cond-assignment-rx id)))
  id              ; => "\\_<\\(?:[[:alpha:]_]+\\|[[:alnum:]_]*\\)\\_>"
  (string-match id "1")                 ; => 0
  (string-match id "a")                 ; => 0
  (string-match id "p111")              ; => 0
  )
(let ((assign (cond-assignment-rx id ws "=" ws id)))
  assign ; => "\\_<\\(?:[[:alpha:]_]+\\|[[:alnum:]_]*\\)\\_>[[:blank:]]*=[[:blank:]]*\\_<\\(?:[[:alpha:]_]+\\|[[:alnum:]_]*\\)\\_>"
  (string-match assign "p111 = a")      ; => 0
  (string-match assign "p111 = 1")         ; => 0
  ;; 【注意】メジャーモード依存！
  ;; emacs-lisp-modeでは p111=1 自体がシンボルになるのでマッチしない
  (string-match assign "p111=1")         ; => nil
  ;; c-modeならばp111と1がシンボルになるのでマッチする
  (with-temp-buffer
    (c-mode)
    (string-match assign "p111=1"))     ; => 0
  )
;;; 条件文にマッチさせる
(let ((cond-assign (cond-assignment-rx cond-keyword ws id ws "==" ws id)))
  cond-assign
  ;; => "\\_<\\(?:elif\\|if\\|while\\)\\_>[[:blank:]]*\\_<\\(?:[[:alpha:]_]+\\|[[:alnum:]_]*\\)\\_>[[:blank:]]*==[[:blank:]]*\\_<\\(?:[[:alpha:]_]+\\|[[:alnum:]_]*\\)\\_>"
  (string-match cond-assign "if p111 == 10") ; => 0
  )